【Excel】ブック全体から特定文字を含むセルを一覧抽出するVBA

タイトルの通り、メールアドレスのドメインなど特定のキーワードが大量のシートに記載されている場合に有用に利用できると思います。
Excelの検索画面で「値」フィールドだけをコピー＆ペーストしたいときに便利です。
なお、「開発」タブを出すとか、標準モジュールを追加するとか、VBAの実行とデバック方法とかは割愛します。
以下のコードをExcelのVBAで実行してください。
抽出されたキーワードを新規タブを作成してリストします。

Sub ListMatchingCellsFromWorkbook()
    Dim ws As Worksheet, resultWs As Worksheet
    Dim cell As Range
    Dim keyword As String
    Dim outputRow As Long

    ' 検索キーワードを指定(サンプルとして当サイトのドメインを記載)
    keyword = "nets-tip"

    ' 結果を出力する新しいシートを作成
    Set resultWs = ThisWorkbook.Sheets.Add
    resultWs.Name = "検索結果"
    outputRow = 1

    ' タイトル行
    With resultWs
        .Cells(1, 1).Value = "シート名"
        .Cells(1, 2).Value = "セルアドレス"
        .Cells(1, 3).Value = "値"
    End With
    outputRow = outputRow + 1

    ' 全シートをループ
    For Each ws In ThisWorkbook.Sheets
        If ws.Name <> resultWs.Name Then
            For Each cell In ws.UsedRange
                If VarType(cell.Value) = vbString Then
                    If InStr(cell.Value, keyword) > 0 Then
                        resultWs.Cells(outputRow, 1).Value = ws.Name
                        resultWs.Cells(outputRow, 2).Value = cell.Address
                        resultWs.Cells(outputRow, 3).Value = cell.Value
                        outputRow = outputRow + 1
                    End If
                End If
            Next cell
        End If
    Next ws

    MsgBox "検索完了しました。"
End Sub

以上、ご参考まで。

関連記事

TOP